BÁO CÁO BÀI TẬP LỚN

MÔN VI XỬ LÝ

Danh sách thành viên :

1, Nguyễn Đức Nam MSSV 20162818

2, Lê Quang Linh MSSV 20162504

Đề tài : Thiết kế hệ thống đèn giao thông ngã tư có sử dụng LED đếm ngược

1. Điều kiện của bài toán

* Thiết kế đèn giao thông tại một ngã tư với 4 cột đèn.
* Mỗi cột đèn sẽ có 3 loại đèn : đèn xanh, đèn vàng và đèn đỏ.
* Thứ tự sáng của các đèn sẽ là xanh – vàng – đỏ – xanh.
* Thời gian sáng của đèn đỏ sẽ bằng tổng cộng thời gian sáng của đèn xanh và đèn vàng.

1. Các điều kiện giả thiết

* Cho thời gian sáng của đèn xanh là 22 giây ; của đèn vàng là 3 giây và của đèn đỏ là 25 giây
* Hai tuyến đường đối diện nhau sẽ bật các đèn giống nhau với thời gian chờ bằng nhau

1. Hướng giải quyết

* Có 4 cột đèn nhưng chỉ cần điều khiển 2 cột đèn nằm trên 2 trục chính của ngã tư
* Ta chia khoảng thời gian sáng của 2 cột đèn thành 4 khoảng đồng thời
* Đèn đỏ bên trục đường 1 và đèn xanh bên trục đường 2
* Đèn đỏ bên trục đường 1 và đèn vàng bên trục đường 2
* Đèn xanh bên trục đường 1 và đèn đỏ bên trục đường 2
* Đèn vàng bên trục đường 1 và đèn đỏ bên trục đường 2
* Ta chỉ cần điều khiển cùng lúc 2 cột đèn trong mỗi một khoảng thời gian trên và thực hiện thao tác quét LED và thực hiện đếm ngược. Khi thời gian đếm ngược về 0 thì chuyển sang khoảng thời gian tiếp theo.

1. Lưu đồ thuật toán



1. Code

XANH\_1 DATA 30h

DO\_1 DATA 31h

VANG\_1 DATA 32h

XANH\_2 DATA 33h

DO\_2 DATA 34h

VANG\_2 DATA 35h

DV\_1 DATA 36h

C\_1 DATA 37h

DV\_2 DATA 38h

C\_2 DATA 39h

LED\_X1 BIT P0.0

LED\_V1 BIT P0.1

LED\_D1 BIT P0.2

LED\_X2 BIT P0.3

LED\_V2 BIT P0.4

LED\_D2 BIT P0.5

LED\_C1 BIT P3.3

LED\_DV1 BIT P3.2

LED\_C2 BIT P3.1

LED\_DV2 BIT P3.0

ORG 000H

LJMP MAIN

ORG 000BH

CLR TR0 ;tat Timer

MOV TL0, #0AFH ;set thoi gian dem 50000

MOV TH0, #03CH ;tuong duong voi 50ms

INC R2 ;tang r2 20 lan de co duoc tre 1s

SETB TR0 ;bat Timer

RETI

ORG 0030H

MAIN:

MOV TMOD, #01H ;su dung timer 0, mode 1

MOV TL0, #0AFH ;nap gia tri ban dau cho TL0,TH0 (k quan trong)

MOV TH0, #03CH

CLR TF0 ;xoa co TF

MOV IE,#10000010B ;cho phep ngat timer 0

START:

;MOV P0,#00001100B ;bat den do 1 va xanh 2

MOV P0,#0

SETB LED\_D1

SETB LED\_X2

MOV XANH\_1,#22 ;nap cac gia tri dau cho xanh,do,vang

MOV DO\_1,#25

MOV VANG\_1,#3

MOV XANH\_2,#22

MOV DO\_2,#25

MOV VANG\_2,#3

SHOW\_D1\_X2:

SETB TR0 ;khoi dong bo timer

MOV R0,DO\_1 ;nap thoi gian den do vao R0

MOV R1, XANH\_2 ;nap thoi gian den xanh vao R1

LCALL TACHSO ;thuc hien tach so trong cac thanh ghi R0 va R1

MOV R2, #0 ;xoa R2

AGAIN\_1:

LCALL HIENTHI ;hien thi cac gia tri ra led

CJNE R2,#18,AGAIN\_1 ;dung vong lap de tao tre 1s dong thoi quet LED lien tuc

DEC DO\_1 ;sau moi vong lap giam gia tri hien thi di 1

DEC XANH\_2

DJNZ R1,SHOW\_D1\_X2

CLR LED\_X2

SETB LED\_V2

;MOV P0,#00010100B ;hien thi den do 1 va vang 2

SHOW\_D1\_V2:

MOV R1,VANG\_2

MOV R0,DO\_1

LCALL TACHSO

MOV R2,#0 ;thuc hien tuong tu cac thao tac o tren

AGAIN\_2:

LCALL HIENTHI

CJNE R2,#18,AGAIN\_2

DEC DO\_1

DEC VANG\_2

DJNZ R1,SHOW\_D1\_V2

CLR LED\_D1

CLR LED\_V2

SETB LED\_X1

SETB LED\_D2

;MOV P0,#00100001B ;hien thi den do 2 va xanh 1

SHOW\_D2\_X1:

MOV R0,XANH\_1

MOV R1,DO\_2

LCALL TACHSO

MOV R2,#0 ;thuc hien tuong tu cac thao tac o tren

AGAIN\_3:

LCALL HIENTHI

CJNE R2,#18,AGAIN\_3

DEC DO\_2

DEC XANH\_1

DJNZ R0,SHOW\_D2\_X1

CLR LED\_X1

SETB LED\_V1

;MOV P0,#00100010B ;hien thi den do 2 va vang 1

SHOW\_D2\_V1:

MOV R0,VANG\_1

MOV R1,DO\_2

LCALL TACHSO

MOV R2,#0 ;thuc hien tuong tu cac thao tac o tren

AGAIN\_4:

LCALL HIENTHI

CJNE R2,#18,AGAIN\_4

DEC DO\_2

DEC VANG\_1

DJNZ R0,SHOW\_D2\_V1

CLR LED\_V1

CLR LED\_D2

LJMP START ;quay lai thuc hien tu dau

;-----------------------

TACHSO: ;tach cac so trong thanh ghi R0 va R1

MOV A,R0 ;tach bien 1

MOV B,#10 ;chia bien 1 cho 10, hang chuc luu vao C\_1 hang don vi luu vao DV\_1

DIV AB

MOV C\_1, A

MOV A,B

MOV DV\_1,A

MOV A,R1 ;tach bien 2

MOV B,#10 ;chia bien 2 cho 10, hang chuc luu vao C\_2 hang don vi luu vao DV\_2

DIV AB

MOV C\_2, A

MOV A,B

MOV DV\_2,A

RET

;-----------------------

HIENTHI: ;hien thi lan luot cac LED su dung chan P1

MOV DPTR,#MALED

SETB LED\_DV1

MOV A,DV\_1

MOVC A, @A + DPTR

MOV P1,A

LCALL DELAY

CLR LED\_DV1

SETB LED\_C1

MOV A,C\_1

MOVC A, @A + DPTR

MOV P1,A

LCALL DELAY

CLR LED\_C1

SETB LED\_DV2

MOV A,DV\_2

MOVC A, @A + DPTR

MOV P1, A

ACALL DELAY

CLR LED\_DV2

SETB LED\_C2

MOV A, C\_2

MOVC A, @A + DPTR

MOV P1, A

ACALL DELAY

CLR LED\_C2

RET

;------------------------

DELAY:

MOV R7, #5

DELAY\_1: MOV R6, #100

DELAY\_2: DJNZ R6, DELAY\_2

DJNZ R7, DELAY\_1

RET

;------------------------

DL\_LED:

MOV R5,#0FFH

DJNZ R5,$

RET

;------------------------

MALED:

DB 0C0H, 0F9H, 0A4H, 0B0H, 099H, 092H, 082H, 0F8H, 080H, 090H

END